Deilson Tavares

// Autor: Prof. Deilson Tavares
// Para o curso "Fractais e Caos na Ciência e na Tecnologia"
 
function [M,y] = deposicao_balistica(K,L,N)
 
  M=zeros(K,L); // Tamanho do sistema max compac.: K ligações atômicas na vertical, L na horizontal. 
  M(1,:)=32*ones(1,L); // A primeira camada é homogênea.
  y = ones(1,L); // Só a primeira camada está preenchida.
  for i = 1:N // Começa a deposição de N átomos.
    x = ceil(L*rand()); // Escolha uma trajetória vertical de deposição ao acaso.
    ys = y(x); // Verifique qual o sítio ativo naquela coluna.
    M(ys,x)=32; // Ligue o novo átomo nesta posição.
    y(x)=ys+1; // O novo sítio ativo está uma camada acima. 
    if x>1 & ys>y(x-1) then // Se o sítio ativo à esqueda é mais baixo
      y(x-1)=ys; // então coloque-o na mesma altura.
    end
    if x<L & ys>y(x+1) then // Se o sítio à direita é mais baixo
      y(x+1)=ys; // então coloque-o na mesma altura.
    end
  end  // Termina a deposição de N átomos.
  M = M([K:-1:1],:); // Reverta a matriz que guarda o aglomerado (melhora a visualização).
endfunction

// Autor: Prof. Deilson Tavares
// Para o curso "Fractais e Caos na Ciência e na Tecnologia".
function M = aglomerado_percolacao_2d(L,p)
 
  M = rand(L,L); // Sorteie um número aleatório entre 0 e 1 para cada volume do sistema (probabilidade uniforme).
  x = find(M<=p); // Veja quais volumes estão associados a números menores ou iguais a p e guarde-os no vetor x.
  M = 32*ones(L,L); // Coloque matéria em todas as posições (convencionamos o código 32 para indicar matéria).
  M(x)=0; // Faça um vazio nas posições designadas pelo vetor x (convencionamos o códico 0 para indicar vazio).
 
endfunction
 
// Observe que o resultado final desta função é preencher a matriz M com 32 ou 0. Os valores 0 aparecem
// com probabilidade p.

// Autor: Prof. Deilson Tavares
// Para o curso "Fractais e Caos na Ciência e na Tecnologia"
// Esta função separa os elementos de uma matriz M preenchida com 0 e 32 em três categorias:
// -- Os zeros são convertidos em 16.
// -- Os elementos 32 que têm contato com um zero são convertidos em 4.
// -- Os elementos 32 que não têm contato com um zero permanecem 32.
// Convencionaremos chamar 16 de vazio, 4 de fronteira ou superfície e 32 de material.
 
function R = separa_elementos(M,g)
// Quando g vale 1 a função mostra uma animação do processo de
// classificação.
 
  if g==1 then
   figure;
   set(gca(),"auto_clear","on")
  end
 
  [k,l]=size(M); // Determine o tamanho da matriz.
  R=M; // Inicialize a matriz resultado R igual a M.
  L=[[1:l]' ones(l,1)]; // Coloque todos os pontos na linha 1 como pontos de sondagem.
  N = l; // O número de pontos de sondagem é o número de colunas.
  while N>0 // Enquanto existirem pontos de sondagem procure classificar seus vizinhos
    Lp=[]; // A lista dos próximos pontos de sondagem é vazia.
    for i = 1:N // Começe a sondagem usando a lista L.
      x = L(i,1);y=L(i,2); // Retire as coordenadas do ponto atual de sondagem da linha i de L.
 
      if x>1 & R(y,x-1)==0 then  //Se o ponto à esqueda de (x,y) for vazio
        R(y,x-1)=16;Lp=[Lp;[x-1 y]]; // então marque-o com 16 e coloque-o na lista de próximos pontos de sondagem.
      elseif x>1 & R(y,x-1)==32 // Se o ponto à esquerda de (x,y) contiver material
        R(y,x-1)=4; // então marque-o como de fronteira.
      end
 
      if x<l & R(y,x+1)==0 then // Exercício: interprete este e os demais testes de condições
        R(y,x+1)=16;Lp=[Lp;[x+1 y]]; // análogos que aparecem até o fim da função
      elseif x<l & R(y,x+1)==32 // de acordo com o modelo que escrevi
        R(y,x+1)=4; // no teste anterior.
      end
 
      if y>1 & R(y-1,x)==0 then
        R(y-1,x)=16;Lp=[Lp;[x y-1]];
      elseif y>1 & R(y-1,x)==32
        R(y-1,x)=4;
      end
 
      if y<k & R(y+1,x)==0 then
        R(y+1,x)=16;Lp=[Lp;[x y+1]];
      elseif y<k & R(y+1,x)==32
        R(y+1,x)=4;
      end
 
    end
    if g==1 then  
      mtlb_image(R);
    end
    L = Lp;
    [N,fake] = size(L);
  end
endfunction